3

I am working with a NEMA-17 Motor (17PM-K310-32VS) with motor driver DRV8225 for which I am following this guide with the exact same circuit they have given but with a addition of one push button programmed to start and stop the motor. I am using AccelStepper and EzButton library for driver and button respectively with following code.

enter image description here

#include <AccelStepper.h>
#include <ezButton.h>

#define MOTOR_SPEED 200
#define dirPin 2
#define stepPin 3
#define motorInterfaceType 1

AccelStepper stepper = AccelStepper(motorInterfaceType, stepPin, dirPin);
ezButton motor_switch(4); 

void setup() 
{
  stepper.setMaxSpeed(200);
  stepper.setSpeed(0);
}

void loop() 
{  
  motor_switch.loop();
  if(motor_switch.isPressed())
  {
    stepper.speed()==0 ? stepper.setSpeed(MOTOR_SPEED) : stepper.setSpeed(0);
  }
  
  if(stepper.speed()==0)
  {
    stepper.stop();
    //stepper.disableInputs();
  }
  else
  {
    //stepper.enableInputs();
    stepper.runSpeed();
  }
}

Problem: Circuit and code works as intended as I am able to start and stop the motor with the push button but I am facing one problem. My NEMA-17 motor vibrates randomly at idle. Frequency of vibration is also random that is sometimes it vibrates for a very short time (less than a second) but other times it vibrates for 5-10 seconds. Also I observed that motor is getting hot even at idle. Why is this happening and how to fix this? Things I have done so far: In order to troubleshoot this, I tried many things:

  1. Changing Arduino, I have tried with UNO, NANO and MEGA.
  2. Changing driver Library and even uploading an empty sketch. (I tried Accelstepper's disableInputs functions as well)
  3. Reviewing connections.
  4. Changing motors.
  5. Replacing Motor driver with another DRV8225 module.
  6. Changing driver's current limit using its potentiometer.

Hoping a find something here. Thank you.

winny
  • 13,064
  • 6
  • 46
  • 63
PrimuSPS
  • 51
  • 5
  • Hello and welcome. I'll guess it's related to your power supply in some way: are you able to measure the current? You may well find more help at Arduino.SE, as this is more of a atandard-modules/arduino/library question that strictly electronics. – jonathanjo Mar 28 '23 at 09:37
  • I am using a 12v adaptor for motor driver. I couldn't measure current as my multimeter doesn't have current support. So I calculate it using the reference voltage i set using the potentiometer present in drv8225. – PrimuSPS Mar 28 '23 at 09:48
  • The driver circuit is probably holding the motor in position. Is there any mechanical load on the motor? My question about current is really wondering not about overall load, but momentary load. Have you tried changing/doubling the capacitor? – jonathanjo Mar 28 '23 at 10:07
  • there is a load on motor. I have tried changing the capacitor as well – PrimuSPS Mar 28 '23 at 10:45

1 Answers1

2

I have been able to fix the problem. Thing I found was motor was not sleeping, I read about SLP and reset pins in DRV8225's manual and found out that SLEEP mode can be controlled using the SLP pin. SLP must be HIGH to disable SLEEP mode and LOW to enable it.

Original guide and many other guides online I found shows direct connection with SLP and RST pins of DRV8825 for easy connections probably targeting beginners. But none of them mentioned the consequences of this direct connection and at best few of them just mentioned the default state for these pins.

So I connected the sleep pin to Arduino digital pins and now I can control the sleep through sketch and have to make sure to enable the SLEEP mode every time I want my motor to STOP and remain idle. So updated code is as follows.

#include <AccelStepper.h>
#include <ezButton.h>

#define MOTOR_SPEED 200
#define dirPin 2
#define stepPin 3
#define motorInterfaceType 1
#define SLEEP_PIN 5

AccelStepper stepper = AccelStepper(motorInterfaceType, stepPin, dirPin);
ezButton motor_switch(4); 

void setup() 
{
  pinMode(SLEEP_PIN,OUTPUT);
  digitalWrite(SLEEP_PIN,LOW);
  delay(2);
  motor_switch.setDebounceTime(50);
  stepper.setMaxSpeed(200);
  stepper.setSpeed(0);
}

void loop() 
{  
  motor_switch.loop();
  if(motor_switch.isPressed())
  {
    if(stepper.speed()==0)  
    {
      digitalWrite(SLEEP_PIN,HIGH);
      delay(2);
      stepper.setSpeed(MOTOR_SPEED) 
    } 
    else
    {
      digitalWrite(SLEEP_PIN,LOW);
      delay(2);
      stepper.setSpeed(0);
    }
  }
  
  if(stepper.speed()==0)
  {
    stepper.stop();
  }
  else
  {
    stepper.runSpeed();
  }
}

Since motor is now sleeping, both vibrations and heat dissipation at idle motor has been gone. I don't know if this heat was the exact reason for vibrations but its fixed as of now.

PrimuSPS
  • 51
  • 5